home *** CD-ROM | disk | FTP | other *** search
/ InterCD 2000 January / january_2000.iso / Site Building / ASPEdit / _SETUP.1 / cookielib.inc < prev    next >
Encoding:
Text File  |  1998-12-22  |  2.5 KB  |  81 lines
  1. <%
  2. '=======================================================================
  3. ' application("cookiedomain") and application("cookiepath") can be 
  4. ' set if firewall precludes accurate server variable
  5. ' 
  6. ' AddCookie(Cname, CKey, CValue, CExpDays)
  7. ' Example: Call AddCookie("MyCookie", "Cost", "$1.00", 100)
  8. '
  9. ' KillCookie(Cname,CKey)
  10. ' Example: Call KillCookie("MyCookie", "Cost")
  11. '
  12. ' GetCookie(Cname,Ckey)
  13. '    Example: Call GetCookie("MyCookie", "Cost")
  14. '
  15. ' Cname = Cookie Name: Required, for cookie name
  16. '    Ckey = Cookie Key: Optional(empty sting), use if cookie should be a dictionary
  17. '    Cvalue = Cookie Value: Required, what the cookie should be set to.
  18. '    CExpDays = Cookie Expiration: number of days cookie is valid, default 365 
  19. '=======================================================================
  20.  
  21. Function AddCookie(Cname, CKey, CValue, CExpDays)
  22.    If Cname = "" Then
  23.       Exit Function
  24.    End If
  25.    
  26.    If IsNumeric(CExpDays) = False Then CExpDays = 0
  27.    If CExpDays < 1 Then CExpDays = 365
  28.    
  29.    If CValue = "" Then CValue = " "
  30.  
  31.    If CKey <> "" Then
  32.       Response.Cookies(Cname)(CKey) = CValue
  33.    Else
  34.       Response.Cookies(Cname) = CValue
  35.    End If
  36.  
  37.    Response.Cookies(CName).Expires = Date + CExpDays
  38.    Response.Cookies(CName).Domain = GetCookieDomain()
  39.    Response.Cookies(CName).Path = GetCookiePath()
  40. End Function
  41.  
  42. Function KillCookie(Cname,CKey)
  43.    If CKey <> "" Then
  44.       Call AddCookie(Cname, Ckey, "", 0)
  45.    Else
  46.       Response.Cookies(Cname).Expires = Date - 365
  47.       Response.Cookies(CName).Domain = GetCookieDomain()
  48.       Response.Cookies(CName).Path = GetCookiePath()
  49.    End If
  50. End Function
  51.  
  52. Function GetCookie(Cname, Ckey)
  53.       If CKey <> "" Then
  54.          GetCookie = Request.Cookies(Cname)(Ckey)
  55.       Else
  56.          GetCookie = Request.Cookies(Cname)
  57.       End If
  58. End Function
  59.  
  60. Function GetCookieDomain()
  61.    If Application("CookieDomain") <> "" Then
  62.       GetCookieDomain = Application("CookieDomain")
  63.    Else
  64.       GetCookieDomain = Request.ServerVariables("SERVER_NAME")
  65.    End If
  66. End Function
  67.  
  68. Function GetCookiePath()
  69.    If Application("CookiePath") <> "" Then
  70.       GetCookiePath = Application("CookiePath")
  71.    Else
  72.       TmpPath = Request.ServerVariables("SCRIPT_NAME")
  73.       TmpPath = Split(TmpPath, "/")
  74.       For PathArryCnt = 0 to Ubound(TmpPath) - 1
  75.          GetCookiePath = GetCookiePath & TmpPath(PathArryCnt) & "/"
  76.       Next
  77.       If GetCookiePath = "/" Then GetCookiePath = ""
  78.    End If
  79. End Function
  80. %>
  81.